<%
Response.Status="301 Moved Permanently"
Response.AddHeader "Location", "/newer-page.asp"
%>

If you are wanting to redirect to your default page name (index.asp,default.asp etc.), it is a good idea to redirect only to the folder name and leave off the name of the page like:

<%
Response.Status="301 Moved Permanently"
Response.AddHeader "Location", "/subfolder/"
%>

The first code snippet is a little function that strips out specified special characters. It basically seeks out any of the characters that exist in the array and removes them all.

<%
Function StripSpecialChar(inStr)
	dim sOut,outStr,arrSpecialChar,intCounter
	 arrSpecialChar  = Array("%20","&amp;","&","#","+","@")
	 outStr = inStr
	 intCounter = 0

	 Do Until intCounter = UBOUND(arrSpecialChar)+1
	  sOut = replace(outStr,arrSpecialChar(intCounter)  ,"")
	  intCounter = intCounter + 1
	  outStr = sOut
	 Loop
	 StripSpecialChar = outStr
end Function
%>

The final snippet is a simple function that will check an array for any occurances of a particular string.

<%
Function in_array(element, arr)
  For i=0 To Ubound(arr)
     If Trim(arr(i)) = Trim(element) Then
        in_array = True
        Exit Function
     Else
        in_array = False
     End If 
  Next
End Function

str = "Apple"
colors = Array("Banana","Apple","Orange")

If in_array(str,colors) Then Response.Write str & " is in the array"
Else Response.Write str & " is not in the array"
End If
%>

I hope you find these functions as useful as I do.

<%
FUNCTION LoadThePage(strPageText, strInputURL)
	Set objXMLHTTP = Server.CreateObject("MSXML2.ServerXMLHTTP")
	objXMLHTTP.Open "GET", strInputURL, False
	objXMLHTTP.Send
	strPageText = objXMLHTTP.responseText
	Set objXMLHTTP = Nothing
End FUNCTION

FUNCTION GrabTheContent(strStart, strEnd)
	Dim strStartPos, strEndPos, strLength
	strStartPos = 0
	strEndPos = 0
	strLength = 0
	'Find the Start Position of the Search String
	strStartPos = instr(strPageText,strStart)
	'Starting from the Search String start position and call it the end position
	strEndPos = instr(strStartPos, strPageText, strEnd)
	'Compute the length of the string in between the start and end positions
	strLength = strEndPos - strStartPos
	'filter the content, use trim to eliminate leading and trailing spaces
	myContent = trim(mid(strPageText,strStartPos, len(strStart))) & "<br/>" & vbCRLF
	myContent = myContent & trim(mid(strPageText,strStartPos + len(strStart), StrLength - len(strStart))) & "<br/>" & vbCRLF
	GrabTheContent = myContent
End FUNCTION

'Declare the string used to hold the HTTP and the start/end strings
Dim strPageText, strStart, strEnd
'Declare and initialize the string used to hold the Input Page URL
Dim strInputURL

if DateDiff("h", Application("updated"), Now()) >=1 then
	strInputURL = "http://www.austmus.gov.au/factSheets/galah.htm"
	'Load the desired page into a string
	LoadThePage strPageText, strInputURL
	strHTML = GrabTheContent("Cacatua roseicapilla","Food and feeding")
	Application.Lock
		Application("content") = strHTML
		Application("updated") = Now()
	Application.Unlock
end if

strHTML = Application("content")
response.write (strHTML)
%>

The code contains two functions, LoadThePage and GrabTheContent, and there names self explain what they perform. LoadThePage saves a copy the external HTML into an XMLHTTP object. GrabTheContent manipulates this object and returns a string that we can use. We give this function two paramters, the text at the start of the section we want to grab and the text that ends what we want to grab. Pretty simple. For this example, we will be using http://www.austmus.gov.au/factSheets/galah.htm as the page we retrieve text from.

Now the main portion of the program firstly it checks the date stamp of the application variable from when it was last cached and if necessary, retrieves a new cache. We do this so we don’t hammer someone else’s website and slow down the performance of our page (and to not annoy the other webserver with heaps of connections). Once we have either retrieved a new cache or used the existing one, we display the contents on the page. So we would see these results:

Ok. So that is nice but how would we format this retrieved text? How do you remove the HTML tags?

To strip the HTML tags, we will be using a function I have previously published named stripHTML. What this function does is strip ALL HTML tags using regex and returns plain text. Now to format the text appearance, we will need to use the string REPLACE function to change/remove/insert tags into appropriate places. Essentially, you scan through the retrieved page and add in the formatting you like. We will finally present this text inside a DIV with an inline style applied. So we would firstly add in the stripHTML function:

<%
FUNCTION stripHTML(strHTML)
  Dim objRegExp, strOutput, tempStr
  Set objRegExp = New Regexp
  objRegExp.IgnoreCase = True
  objRegExp.Global = True
  objRegExp.Pattern = "<(.|n)+?>"
  'Replace all HTML tag matches with the empty string
  strOutput = objRegExp.Replace(strHTML, "")
  'Replace all < and > with &lt; and &gt;
  strOutput = Replace(strOutput, "<", "&lt;")
  strOutput = Replace(strOutput, ">", "&gt;")
  stripHTML = strOutput    'Return the value of strOutput
  Set objRegExp = Nothing
END FUNCTION
>%

And finally, we would change how the text is presented at the bottom of the script to this:

<%
strHTML = Application("content")
strHTML = stripHTML(strHTML)
strHTML = REPLACE(strHTML,"Cacatua roseicapilla","<B>Cacatua Roseicapilla</B><br/><br/>")
strHTML = REPLACE(strHTML,"Description","<b style='font:bold 12px/15px Arial,Helvetica;color:#cc0000;'>Description</b><br/>")
strHTML = REPLACE(strHTML,"Distribution and Habitat ","<br/><br/><b style='font:bold 12px/15px Arial, Helvetica;color:#cc0000;'>Distribution and Habitat </b><br/>")
response.write "<DIV style='width:250px;font:normal 12px/15px Arial,Helvetica;color:#333333;text-align:justify;'>" & strHTML & "</div>"
%>

So let’s take a look at how it appears now:

There you go, much better. Exactly the same results as the first example but much more readable and adaptable to your site after using your formatting. Hopefully you find this useful one day.

<%
if DateDiff("h", Application("rss-html-time"), Now()) >=1 then
    extURL = "http://newsrss.bbc.co.uk/rss/newsonline_world_edition/front_page/rss.xml"

    set xmlDoc = createObject("Msxml.DOMDocument")
    xmlDoc.async = false
    xmlDoc.setProperty "ServerHTTPRequest", true
    xmlDoc.load(extURL)
    ' Check RSS is correct
    if (xmlDoc.parseError.errorCode <> 0) then
	Response.Write "XML error: " & xmlDoc.parseError.reason
    else
	set itemNodes = xmlDoc.selectNodes("//item/*")
	for each item in itemNodes
	        if item.tagName = "title" then
			strItemTitle = strItemTitle & item.text & "#%#"
		elseif item.tagName = "link" then
			strItemLink = strItemLink & item.text & "#%#"
		elseif item.tagName = "description" then
			strItemDescription = strItemDescription & item.text & "#%#"
		end if
	next
	arrItemTitle = split(strItemTitle,"#%#")
	arrItemLink = split(strItemLink,"#%#")
	arrItemDescription = split(strItemDescription,"#%#")

	strHTML = "<DIV id=feed>"
	for a = 0 to UBound(arrItemTitle) - 1
                strHTML = strHTML & "<div id=article" & a & ">"
		strHTML = strHTML & "<a href='" & arrItemLink(a) & "'>" & arrItemTitle(a) & "</a>"
		if strItemDescription <> "" then
			strHTML = strHTML & "" & arrItemDescription(a)
		end if
                strHTML = strHTML & "</div>"
	next
	strHTML = strHTML & "</div>"
	set channelNodes = nothing
	set itemNodes = nothing
	Application.Lock
		Application("rss-html") = strHTML
		Application("rss-html-time") = Now()
	Application.Unlock
    end if
end if

set xmlDoc = nothing
response.write(Application("rss-html"))
%>

Essentially, the script checks the timestamp of the application variable, and if it has been longer than 1 hour, it will reload the RSS feed into an application variable, otherwise it will use the existing content inside the application variable rss-html. If the script needs to retrieve the RSS feed, it loads it into a DOM object and then parses the RSS looking for <item> tags. We then create a string for each of the RSS fields we are interested in storing. Whiel we parse each <item> we add a delimiter inside these strings “#%#” to separate the entries. Once we have finished parsing the RSS, we are left with three strings.

We now split these strings into arrays using the split function, seeking the delimiter “#%#” we previously used. Once the elements are inside three arrays, we loop through with a FOR loop until we reach the end of the arrays. We can process each of the elements as we loop through and format as required. The reason I prefer not to feed the RSS straight into an array is because we would need to determine the number of records and redim the array, where as with the method I have used, you create a concatenated string that can be easily split later at the delimiters and feed into an array.

I hope you find this useful.

The first code snippet is a little function that converts text into mixed case, or sentance case. It basically seeks out spaces in a string and converts the first character after thhe space to a capitalized letter and the remaining characters before the next space to lower case.

<%
Function MixedCase(strInput)
Dim strPos, strSpace, strOutput
' Set our position variable to the start of the string.
strPosition = 1
' Loop to check spaces
Do While InStr(strPosition, strInput, " ", 1) <> 0
     strSpace = InStr(strPosition, strInput, " ", 1)
     strOutput = strOutput & UCase(Mid(strInput, strPosition, 1))
     strOutput = strOutput & LCase(Mid(strInput, strPosition + 1, strSpace - strPosition))
     strPosition = strSpace + 1
Loop
' Last word is currently uncapitalized - fix this
strOutput = strOutput & UCase(Mid(strInput, strPosition, 1))
strOutput = strOutput & LCase(Mid(strInput, strPosition + 1))
MixedCase = strOutput
End Function
%>

ASP seems to lack a URL Decode function but has a URL Encode function available. Here is a function that can decode any URL Encoded URL or variable. I found this script a while ago on another site and have used it when necessary.

<%
Function URLDecode(str)
Dim re
Set re = new RegExp
str = Replace(str, "+", " ")
re.Pattern = "%([0-9a-fA-F]{2})"
re.Global = True
URLDecode = re.Replace(str, GetRef("URLDecodeHex"))
end function

' Replacement function for the above
Function URLDecodeHex(match, hex_digits, pos, source)
	URLDecodeHex = chr("&H" & hex_digits)
End Function
%>

Here is a practical example of when you would use the URLDecode function – to record the search terms someone has use to find your site in Google. This functions examines the string to see if it contains “google.” and if it does, assumes the string contains google keywords and seeks out “q=” inside the string. If it also finds this, the stripStr is now created with the prefix “GOOGLE:” and the key words are appended to the end.

<%
FUNCTION StripGoogleTerms(stripStr)
	stripStr = URLDecode(stripStr)
	IF InStr(stripStr, "google.") THEN 'Google Refer
		WordArray = Split(stripStr, "&")
		FOR i = LBound(WordArray) TO UBound(WordArray)
			pos = InStr(WordArray(i), "q=")
			IF pos <> 0 THEN
			   tempStr = "GOOGLE:" & MID(WordArray(i),pos+2)
			END IF
		NEXT
	ELSE 'do nothing
		tempStr = stripStr
	END IF
	StripGoogleTerms = tempStr
END FUNCTION
%>

This string function is a function that returns the name of the script/asp page currently being browsed, minus the path name and the .asp at the end. I find this very useful when used inside a header include file where you wish to have ‘dynamically inserted’ title tags, meta tags and the like.

<%
FUNCTION GetScriptLocation(callerURL,partURL)
'Split the path along the /s. This creates a one-dimensional array
arPath = Split(callerURL, "/")
' The last item in the array contains the file name
script_name = arPath(UBound(arPath,1))
script_name = Replace(script_name,".asp","")
GetScriptLocation = script_name
END FUNCTION
%>

Here is an example of the above function used in the method that I mentioned before. It is very useful to make your include files dynamic so you don’t have duplicate header information on every file, just because you share the same header include. This assists with basic SEO and ensuring each page is different, which is sometimes a problem on dynamic sites.

<%
scriptName = GetScriptLocation(Request.ServerVariables("script_name"))
siteName = "My Site"
SELECT CASE script_name
CASE "default"
	MainHeading = "Home Page"
	keywords = "home page, welcome"
	descript = "Welcome to my home page"
CASE "about-us"
	MainHeading = "About Us"
	keywords = "about us"
	descript = "Find out more about us"
%>
<html>
<head>
<TITLE><%=siteName%> :: <%=MainHeading%></TITLE>
<META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=iso-8859-1">
<META name="Keywords" content="<%=keywords%>">
<META name="Description" content="<%=descript%>">
....

The final string function is a short and sweet function that will strip HTML tags out of any string. It uses regex expressions and is very fast.

<%
FUNCTION stripHTML(strHTML)
  Dim objRegExp, strOutput, tempStr
  Set objRegExp = New Regexp
  objRegExp.IgnoreCase = True
  objRegExp.Global = True
  objRegExp.Pattern = "<(.|n)+?>"
  'Replace all HTML tag matches with the empty string
  strOutput = objRegExp.Replace(strHTML, "")
  'Replace all < and > with &lt; and &gt;
  strOutput = Replace(strOutput, "<", "&lt;")
  strOutput = Replace(strOutput, ">", "&gt;")
  stripHTML = strOutput    'Return the value of strOutput
  Set objRegExp = Nothing
END FUNCTION

I hope you find these functions as useful as I do.